Day 66 - Terraform Hands-on Project - Build Your Own AWS Infrastructure with Ease using Infrastructure as Code (IaC)
Welcome back to your Terraform journey.
In the previous tasks, you have learned about the basics of Terraform, its configuration file, and creating an EC2 instance using Terraform. Today, we will explore more about Terraform and create multiple resources.
Task 1:
Create a VPC (Virtual Private Cloud) with CIDR block 10.0.0.0/16
Connect to our EC2 instance and add the following code to our Terraform configuration in main.tf file
resource "aws_vpc" "main" {
cidr_block = "10.0.0.0/16"
tags = {
Name = "main"
}
}
Then our main.tf file will look like this:
terraform{
required_providers {
aws = {
source = "hashicorp/aws"
version = "~> 4.16"
}
}
required_version = ">=1.2.0"
}
provider "aws" {
region = "us-east-1"
}
resource "aws_vpc" "main" {
cidr_block = "10.0.0.0/16"
tags = {
Name = "main"
}
}
Run terraform init , terraform plan , and terraform apply to build the VPC
Verify the newly created VPC named 'main' in the AWS VPC Management Console.
Task 2:
Create a public subnet with CIDR block 10.0.1.0/24 in the above VPC.
resource "aws_subnet" "public_subnet" {
vpc_id = aws_vpc.main.id
cidr_block = "10.0.1.0/24"
tags = {
Name = "Public Subnet"
}
}
This code creates a public subnet resource named “public_subnet” with the specified CIDR block
Run terraform apply to create the public subnet in your AWS account.
Go to VPC console and click on "subnets" to verify that the public subnet is created.
Task 3:
Create a private subnet with CIDR block 10.0.2.0/24 in the above VPC.
resource "aws_subnet" "private_subnet" {
vpc_id = aws_vpc.main.id
cidr_block = "10.0.2.0/24"
tags = {
Name = "Private Subnet"
}
}
Run terraform apply to build the VPC.
Go to VPC console and click on "subnets" to verify that the private subnet is created.
Task 4:
Create an Internet Gateway (IGW) and attach it to the VPC.
resource "aws_internet_gateway" "gw" {
vpc_id = aws_vpc.main.id
tags = {
Name = "igw"
}
}
Run terraform apply to create the VPC
Go to VPC console and click on "internet gateways" to verify that the internet gateway is created.
Task 5:
Create a route table for the public subnet and associate it with the public subnet. This route table should have a route to the Internet Gateway.
resource "aws_route_table" "public" {
vpc_id = aws_vpc.main.id
route {
cidr_block = "0.0.0.0/0"
gateway_id = aws_internet_gateway.gw.id
}
tags = {
Name = "route-table"
}
}
resource "aws_route_table_association" "public" {
subnet_id = aws_subnet.public_subnet.id
route_table_id = aws_route_table.public.id
}
First create a route table for public subnet.
aws_route_table block creates a new route table in the VPC specified by vpc_id attribute. It also defines a route that sends all traffic with destination CIDR 0.0.0.0/0 to the internet gateway specified by gateway_id attribute. The tags attribute sets a name for the route table for easy identification.
Then associate route table with public subnet.
aws_route_table_association block associates the newly created route table with a public subnet specified by the subnet_id attribute. The route_table_id attribute refers to the ID of the route table created in the previous block.
Run terraform apply to create the route table.
The route table is successfully created.
Route table is associated with public subnet using terraform.
Task 6:
Launch an EC2 instance in the public subnet with the following details:
AMI
Instance type: t2.micro
aws_instance block creates a new EC2 instance in the public subnet specified by subnet_id attribute. It uses the Amazon Machine Image (AMI) ID ami-0c7217cdde317cfec, which is a Ubuntu 22.04.3 LTS image. The key_name attribute specifies the name of the key pair used to SSH into the instance. The vpc_security_group_ids attribute specifies a list of security groups to attach to the instance, in this case, it refers to the ID of the security group created in the next block.
resource "aws_instance" "web_server" {
ami = "ami-0c7217cdde317cfec"
instance_type = "t2.micro"
subnet_id = aws_subnet.public_subnet.id
vpc_security_group_ids = [aws_security_group.ssh_access.id]
Security group: Allow SSH access from anywhere
aws_security_group block creates a new security group that allows inbound traffic on ports 22 (SSH) and 80 (HTTP) from any source (0.0.0.0/0). The name_prefix attribute sets a name prefix for the security group, and the vpc_id attribute specifies the ID of the VPC where the security group will be created.
resource "aws_security_group" "ssh_access" {
name_prefix = "ssh_access"
vpc_id = aws_vpc.main.id
ingress {
from_port = 80
to_port = 80
protocol = "tcp"
cidr_blocks = ["0.0.0.0/0"]
}
ingress {
from_port = 22
to_port = 22
protocol = "tcp"
cidr_blocks = ["0.0.0.0/0"]
}
egress {
from_port = 0
to_port = 0
protocol = -1
cidr_blocks = ["0.0.0.0/0"]
}
}
Task 7:
User data: Use a shell script to install Apache and host a simple website
The user_data attribute specifies the script to run when the instance is launched. This script updates the package manager, installs Apache web server, creates a basic HTML file, and restarts Apache.
user_data = <<-EOF
#!/bin/bash
# Update the package list
sudo apt update
# Install Apache
sudo apt install -y apache2
sudo cat <<HTML > /var/www/html/index.html
<!DOCTYPE html>
<html><body><h1>Welcome to my website</h1></body></html>
HTML
sudo systemctl restart apache2
EOF
Task 9:
Create an Elastic IP and associate it with the EC2 instance.
aws_eip block creates a new Elastic IP address and associates it with the instance created in the first block by specifying the instance ID in the instance attribute. The tags attribute sets a name for the Elastic IP for easy identification.
resource "aws_eip" "eip" {
instance = aws_instance.web_server.id
vpc = true
tags = {
Name = "elastic-ip"
}
Task 10:
Combine all the configurations to spin up the EC2 instance
Launch an EC2 instance in the public subnet with the following details:
AMI: ami-0c7217cdde317cfec
Instance type: t2.micro
Security group: Allow SSH access from anywhere
User data: Use a shell script to install Apache and host a simple website
Create an Elastic IP and associate it with the EC2 instance.
resource "aws_security_group" "ssh_access" {
name_prefix = "web-server-sg"
vpc_id = aws_vpc.main.id
ingress {
from_port = 80
to_port = 80
protocol = "tcp"
cidr_blocks = ["0.0.0.0/0"]
}
ingress {
from_port = 22
to_port = 22
protocol = "tcp"
cidr_blocks = ["0.0.0.0/0"]
}
egress {
from_port = 0
to_port = 0
protocol = -1
cidr_blocks = ["0.0.0.0/0"]
}
}
resource "aws_instance" "web_server" {
ami = "ami-0c7217cdde317cfec"
instance_type = "t2.micro"
subnet_id = aws_subnet.public_subnet.id
vpc_security_group_ids = [aws_security_group.ssh_access.id]
user_data = <<-EOF
#!/bin/bash
# Update the package list
sudo apt update
# Install Apache
sudo apt install -y apache2
sudo cat <<HTML > /var/www/html/index.html
<!DOCTYPE html>
<html><body><h1>Welcome to my website</h1></body></html>
HTML
sudo systemctl restart apache2
EOF
tags = {
Name = "terraform-instance"
}
}
resource "aws_eip" "ip" {
instance = aws_instance.web_server.id
vpc = true
tags = {
Name = "elastic-ip"
}
}
Run terraform apply
We can now view the new EC2 instance (terraform-instance) in the AWS console.
Open the website URL in a browser to verify that the website is hosted successfully.
Thank you...